Satomi's Whiteboard

前提条件

• Ubuntu 24.04.3 LTS
• FFmpeg インストール済み (version 6.1.1-3ubuntu5)
• Asterisk で通話可能になっている
• 文字コードは UTF-8 で統一

準備1 音声を生成するためのもの (OpenJTalk + MMDAgent)

インストール

$ sudo apt install open-jtalk open-jtalk-mecab-naist-jdic hts-voice-nitech-jp-atr503-m001
$ : MMDAgent から音声モデルをいただきます
$ wget https://sourceforge.net/projects/mmdagent/files/MMDAgent_Example/MMDAgent_Example-1.8/MMDAgent_Example-1.8.zip
$ unzip MMDAgent_Example-1.8.zip
$ sudo mv MMDAgent_Example-1.8/Voice/mei /usr/share/hts-voice/
$ : 発声が出来るか確認
$ echo "10分" | open_jtalk -m /usr/share/hts-voice/mei/mei_normal.htsvoice -x /var/lib/mecab/dic/open-jtalk/naist-jdic -ow /tmp/voice.wav -g 15 && aplay /tmp/voice.wav

文字列を Asterisk 用音声に変換するスクリプトを用意

#!/usr/bin/perl

use strict;
use warnings;

my $VOICE     = '/usr/share/hts-voice/mei/mei_normal.htsvoice';
my $DICT      = '/var/lib/mecab/dic/open-jtalk/naist-jdic';
my $OTHER_OPT = '';

my($text, $output_wav) = @ARGV;

my $TEMP_WAV  = "/var/tmp/$$.wav";

open(my $pipe, '|-', "/usr/bin/open_jtalk -m $VOICE -x $DICT -ow $TEMP_WAV $OTHER_OPT") or die;
print $pipe $text;
close $pipe;

system("ffmpeg -i $TEMP_WAV -af 'aformat=sample_rates=8000' -loglevel quiet -y $output_wav");
unlink($TEMP_WAV);

exit;

準備2 受付・キャンセル用スクリプトの用意

#!/usr/bin/perl -w

use v5.12;

use FindBin;
chdir $FindBin::Bin or die;

use Getopt::Long qw(:config posix_default no_ignore_case gnu_compat);


my $OUT_SPOOL = '/var/spool/asterisk/outgoing';
my $TEMP_DIR  = '/var/tmp';
my $SOUND_EXT = '279';  #モーニングコール音源につながる内線番号

my($action, $time, $caller, $answer_wav);
GetOptions('answer-wav=s' => \$answer_wav,
           'action=s'     => \$action,
           'time=s'       => \$time,
           'caller=s'     => \$caller,
                                        ) or die 'Invalid options';

my $answer_text = '';

if( $action =~ /REGISTER/i && $time =~ /^(\d{2})(\d{2})$/ && $1 <= 23 && $2 <= 59){
    my($h, $m) = ($1, $2);

    cancel($caller);

    my ($date, $today_or_tomorrow) = get_date_at_the_time($time);
    register($date, $time, $caller);

    $h =~ s/^0//;
    $m =  $m==0 ? 'ちょうど'
         :$m==30? '半'
         :( int($m). "分" );

    $answer_text = "モーニングコールを $today_or_tomorrowの $h時$mにセットしました";

}elsif( $action =~ /CANCEL/i ) {
    cancel($caller);
    $answer_text = "モーニングコールをキャンセルしました";

}else{
    $answer_text = "無効な指定です";
}

system("./jtalk2wav.pl '$answer_text' $answer_wav") if $answer_wav;
say $answer_text;

exit;



#コールをセット.
sub register {
    my($date, $time, $caller_ext) = @_;

    my $file = "$TEMP_DIR/morning-call-$caller_ext-$date-$time.txt";
    open(my $fh, '>', $file) or die("Cannot create $file");

    my $body = << "    EOM";
        Channel: PJSIP/$caller_ext
        CallerID: Good_Morning!!
        MaxRetries: 0
        RetryTime: 300
        WaitTime: 30
        Context: ipdenwa
        Extension: $SOUND_EXT
        Archive: yes
    EOM

    $body =~ s/^\s+//gm;
    print $fh $body;

    system("touch --date='$date $time' $file");
    system("mv $file $OUT_SPOOL");
}



#指定内線番号の登録をすべて解除.
sub cancel {
    my($caller_ext) = @_;

    unlink glob("$OUT_SPOOL/morning-call-$caller_ext-*.txt");
}



#指定された時刻に応じて ( 今日or明日の日付(ISO8601),  文字列「今日」or「明日」 ) をリストで返す.
sub get_date_at_the_time {
    #時刻は3~4桁の数値で指定
    my($time) = @_;

    my $date;
    my $today_or_tomorrow;

    my $now_time = int(`date +%H%M`);

    #現在時刻が 指定時刻を過ぎていたら
    if( $time <= $now_time ){
        $today_or_tomorrow = '明日';
        $date = `date --iso-8601 --date 1day`;
    }else{
        $today_or_tomorrow = '今日';
        $date = `date --iso-8601`;
    }

    chomp $date;
    return ($date, $today_or_tomorrow);
}

準備3 モーニングコール音源の用意

準備4 extensions.conf への追記

[house]

(...中略...)

; 277xxxx モーニングコール 登録
exten => _277XXXX,1,NoOp(REGISTER-MORNINGCALL)
same  => n,Answer
same  => n,Playback(beep)
same  => n,Set(ANSWER_WAV_BASENAME=/var/tmp/morning-call-answer-$CALLERID(num))
same  => n,System(/usr/bin/rm $ANSWER_WAV_BASENAME.wav)
same  => n,System(/usr/local/bin/asterisk-utils/morning-call.pl --action register --time '$EXTEN:3' --caller '$CALLERID(num)' --answer-wav $ANSWER_WAV_BASENAME.wav)
same  => n,Playback($ANSWER_WAV_BASENAME)
same  => n,System(/usr/bin/rm $ANSWER_WAV_BASENAME.wav)
same  => n,Wait(1)
same  => n,Playback(beep)
same  => n,Hangup

; 278 モーニングコール 取り消し
exten => _278,1,NoOp(CANCEL-MORNINGCALL)
same  => n,Answer
same  => n,Playback(beep)
same  => n,Set(ANSWER_WAV_BASENAME=/var/tmp/morning-call-answer-$CALLERID(num))
same  => n,System(/usr/bin/rm $ANSWER_WAV_BASENAME.wav)
same  => n,System(/usr/local/bin/asterisk-utils/morning-call.pl --action cancel --caller '$CALLERID(num)' --answer-wav $ANSWER_WAV_BASENAME.wav)
same  => n,Playback($ANSWER_WAV_BASENAME)
same  => n,System(/usr/bin/rm $ANSWER_WAV_BASENAME.wav)
same  => n,Wait(1)
same  => n,Playback(beep)
same  => n,Hangup

; 279 きみの朝
exten => 279,1,Answer
same  => n,Wait(1)
same  => n,Playback(/var/lib/asterisk/sounds/asadayo)
same  => n,Hangup

使い方

セット

キャンセル

参考

• Asteriskでモーニングコール（超簡単版）
• OpenJTalk + python で日本語テキストを発話